Início
/
Projetos Arduino
/
Jogos
/
Jogo da Memória (Genius) - arduino jogo #03
Jogo da Memória (Genius) - arduino jogo #03
Angelo Luis Ferreira | 14/01/2020
Acessos: 29.338
Jogo 3 : Genius - Jogo da Memória
Objetivo
Neste projeto vamos apresentar o "Jogo da Memória" também chamado de "Genius", jogo de grande sucesso na década de 80. O jogo apresenta 4 botões e 4 leds que acenderão em uma sequência aleatória, com sons definidos para cada um dos leds. O jogador deverá clicar nos botões de acordo com a sequência gerada pela Arduino. A cada jogada, a sequência é acrescida de um novo item. Ganha quem conseguir repetir a maior sequência possível. O jogo é limitado a 100 jogadas, mas você poderá aumentar se desejar.
Aplicação
Para fins didáticos.
Componentes necessários
Montagem do Circuito - Simulação
Conecte os componentes no Protoboard como mostra a figura abaixo. Verifique cuidadosamente os cabos de ligação antes de ligar seu Arduino. Lembre-se que o Arduino deve estar totalmente desconectado da força enquanto você monta o circuito.
Atenção
1) Lembre-se que o LED tem polaridade: O terminal maior tem polaridade positiva e o lado do chanfro tem polaridade negativa.
2) Determinamos o valor do resistor através da tabela prática: Tabela prática de utilização de leds 3mm e 5mm. Entretanto, o mais correto é sempre verificar o datasheet do fabricante do LED para você ter os exatos valores de tensão e corrente do mesmo - leia Leds ligados em série e em paralelo.
2.1. Valores mínimos utilizados para nossos projetos: LEDs difusos ou de alto brilho: Vermelho, Laranja e Amarelo: 150 Ω | Led Verde e Azul: 100 Ω
3) O buzzer tem polaridade. Portando, cuidado para não ligar o buzzer invertido. Se você retirar o adesivo superior do buzzzer poderá ver um sinal de positivo (+). Este sinal mostra onde está o pino positivo do componente que deverá estar conectado (neste projeto) a uma porta digital do Arduino e o polo negativo ao GND.
4) Monte o botão (push button) sem o resistor, pois através da programação vamos habilitar o resistor pull-up interno do arduino. Desta forma, quando o botão estiver pressionado, o Arduino retornará "LOW" ou "0". Assista o vídeo Arduino: Botão e Resistor de Pull Up Interno
5) Veja abaixo como ficou a montagem do nosso projeto:
Obs.: Os botões utilizados abaixo funcionam da mesma forma que qualquer outro modelo de "push button" (chave táctil) que você possua.
Código do Projeto (Sketch)
1. Faça o dowload e abra o arquivo jogo3.ino no IDE do Arduino: DOWNLOAD - jogo3.ino
2. Se preferir, copie e cole no IDE do Arduino:
/*******************************************************************************
*
* Jogo 3 - Jogo Genius
* Criado por: https://meetarduino.wordpress.com
* Adaptado por: Angelo Luis Ferreira
*
* http://squids.com.br/arduino
*
*******************************************************************************/
//Vamos começar definindo as notas para os sons
#define NOTE_D4 294
#define NOTE_G4 392
#define NOTE_A4 440
#define NOTE_A5 880
// criando o array para os 4 sons para sortear um som
int tons[4] = { NOTE_A5, NOTE_A4, NOTE_G4, NOTE_D4 };
// Nossa sequência de até 100 itens vai começar vazia.
int sequencia[100] = {};
// Indica a rodada atual que o jogo se encontra.
int rodada_atual = 0;
// Indica o passo atual dentro da sequência, é usado enquanto a sequência
// está sendo reproduzida.
int passo_atual_na_sequencia = 0;
/*
* Indica o pino de áudio, leds e botões.
* Os pinos de leds e botões estão em ordem, relacionados uns aos outros, ou
* seja, o primeiro led está relacionado ao primeiro botão. A ordem destas
* sequências também estão relacionadas a ordem dos tons.
*/
int pinoAudio = 12;
int pinosLeds[4] = { 2, 4, 6, 8 };
int pinosBotoes[4] = { 3, 5, 7, 9 };
// Indica se um botão foi pressionado durante o loop principal.
int botao_pressionado = 0;
// Flag indicando se o jogo acabou.
int perdeu_o_jogo = false;
void setup() {
// Definindo o modo dos pinos dos Leds como saída.
for (int i = 0; i <= 3; i++) {
pinMode(pinosLeds[i], OUTPUT);
}
// Definindo o modo dos pinos dos Botões como pullup interno.
for (int i = 0; i <= 3; i++) {
pinMode(pinosBotoes[i], INPUT_PULLUP);
}
// Definindo o modo do pino de Áudio como saída.
pinMode(pinoAudio, OUTPUT);
// Inicializando o random através de uma leitura da porta analógica.
// Esta leitura gera um valor variável entre 0 e 1023.
randomSeed(analogRead(0));
}
void loop() {
// Se perdeu o jogo reinicializamos todas as variáveis.
if (perdeu_o_jogo) {
int sequencia[100] = {};
rodada_atual = 0;
passo_atual_na_sequencia = 0;
perdeu_o_jogo = false;
}
// Toca um som de início para anúnicar que o jogo está começando quando é a primeira rodada.
if (rodada_atual == 0) {
tocarSomDeInicio();
delay(500);
}
// Chama a função que inicializa a próxima rodada.
proximaRodada();
// Reproduz a sequência atual.
reproduzirSequencia();
// Aguarda os botões serem pressionados pelo jogador.
aguardarJogador();
// Aguarda 1 segundo entre cada jogada.
delay(1000);
}
// Sorteia um novo item e adiciona na sequência.
void proximaRodada() {
int numero_sorteado = random(0, 4);
sequencia[rodada_atual++] = numero_sorteado;
}
// Reproduz a sequência para ser memorizada.
void reproduzirSequencia() {
for (int i = 0; i < rodada_atual; i++) {
tone(pinoAudio, tons[sequencia[i]]);
digitalWrite(pinosLeds[sequencia[i]], HIGH);
delay(500);
noTone(pinoAudio);
digitalWrite(pinosLeds[sequencia[i]], LOW);
delay(100);
}
noTone(pinoAudio);
}
// Aguarda o jogador iniciar sua jogada.
void aguardarJogador() {
for (int i = 0; i < rodada_atual; i++) {
aguardarJogada();
// verifica a jogada
if (sequencia[passo_atual_na_sequencia] != botao_pressionado) {
gameOver(); // perdeu
}
// para o jogo se perdeu
if (perdeu_o_jogo) {
break;
}
passo_atual_na_sequencia++;
}
// Redefine a variável para 0.
passo_atual_na_sequencia = 0;
}
void aguardarJogada() {
boolean jogada_efetuada = false;
while (!jogada_efetuada) {
for (int i = 0; i <= 3; i++) {
if (!digitalRead(pinosBotoes[i])) {
// Dizendo qual foi o botao pressionado.
botao_pressionado = i;
tone(pinoAudio, tons[i]);
digitalWrite(pinosLeds[i], HIGH);
delay(300);
digitalWrite(pinosLeds[i], LOW);
noTone(pinoAudio);
jogada_efetuada = true;
}
}
delay(10);
}
}
void gameOver() {
// GAME OVER.
for (int i = 0; i <= 3; i++) {
tone(pinoAudio, tons[i]);
digitalWrite(pinosLeds[i], HIGH);
delay(200);
digitalWrite(pinosLeds[i], LOW);
noTone(pinoAudio);
}
tone(pinoAudio, tons[3]);
for (int i = 0; i <= 3; i++) {
digitalWrite(pinosLeds[0], HIGH);
digitalWrite(pinosLeds[1], HIGH);
digitalWrite(pinosLeds[2], HIGH);
digitalWrite(pinosLeds[3], HIGH);
delay(100);
digitalWrite(pinosLeds[0], LOW);
digitalWrite(pinosLeds[1], LOW);
digitalWrite(pinosLeds[2], LOW);
digitalWrite(pinosLeds[3], LOW);
delay(100);
}
noTone(pinoAudio);
perdeu_o_jogo = true;
}
void tocarSomDeInicio() {
tone(pinoAudio, tons[0]);
digitalWrite(pinosLeds[0], HIGH);
digitalWrite(pinosLeds[1], HIGH);
digitalWrite(pinosLeds[2], HIGH);
digitalWrite(pinosLeds[3], HIGH);
delay(500);
digitalWrite(pinosLeds[0], LOW);
digitalWrite(pinosLeds[1], LOW);
digitalWrite(pinosLeds[2], LOW);
digitalWrite(pinosLeds[3], LOW);
delay(500);
noTone(pinoAudio);
}
Vídeo
Como o projeto deve funcionar
1. Ao executar o programa, todos os leds acenderão e é dado um sinal sonoro.
2. Aleatoriamente, acenderá o primeiro led entre os 4 leds do jogo. O programa irá aguardar que o jogador clique no botão correspondente.
2.1. Cada led aceso tem um som correspondente.
3. Se o jogador acertar o botão, repete-se a sequência com o acréscimo aleatório do segundo led.
4. Se o jogador errar, acenderá um sinal sonoro indicando o fim do jogo. Novo led se acenderá....
5. Ganha o jogador que acertar mais jogadas, ou seja, memorizar a maior sequência de sons.
Créditos
Este projeto foi uma adaptação do projeto original: https://meetarduino.wordpress.com/2012/05/27/arduino-genius-jogo-da-memoria/
Desafios
Com base neste projeto, resolva os seguintes desafios: Desafio 65
O anúncio abaixo ajuda a manter o Squids Arduino funcionando
Comentários
